Repository navigation
Expand file tree
/
Copy pathflake.nix
More file actions
81 lines (77 loc) · 1.95 KB
/
Copy pathflake.nix
File metadata and controls
81 lines (77 loc) · 1.95 KB
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
{
description = "co: the co.codes command-line client";
inputs = {
nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
flake-utils.url = "github:numtide/flake-utils";
};
outputs =
{
self,
nixpkgs,
flake-utils,
}:
flake-utils.lib.eachDefaultSystem (
system:
let
pkgs = import nixpkgs { inherit system; };
package = pkgs.buildGo126Module {
pname = "co-codes-cli";
version = builtins.head (
builtins.match ".*var Version = \"([^\"]+)\".*" (builtins.readFile ./internal/cli/version.go)
);
src = self;
vendorHash = "sha256-5NFjKo59hfV0Y+2pQ+1URJHrIZu6DsuABrA93Q3v7gY=";
subPackages = [ "cmd/co" ];
env.CGO_ENABLED = 0;
ldflags = [
"-s"
"-w"
];
nativeCheckInputs = [
pkgs.git
pkgs.python3
];
checkPhase = ''
runHook preCheck
export CO_TEST_GO_BINARY="$GOPATH/bin/co"
go test ./... -count=1
runHook postCheck
'';
meta = {
description = "Human-facing CLI for co.codes";
homepage = "https://co.codes";
license = with pkgs.lib.licenses; [
mit
asl20
];
mainProgram = "co";
platforms = pkgs.lib.platforms.unix;
};
};
in
{
packages = {
co = package;
default = package;
};
apps = {
co = {
type = "app";
program = pkgs.lib.getExe package;
};
default = {
type = "app";
program = pkgs.lib.getExe package;
};
};
devShells.default = pkgs.mkShell {
packages = [
pkgs.go_1_26
pkgs.git
pkgs.nodejs_24
pkgs.shellcheck
];
};
}
);
}