mycode/justfile at main · legibet/mycode · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
set shell := ["bash", "-uc"]
set dotenv-load

alias help := default
alias install := setup
alias dev := web-dev
alias api := web-backend
alias backend := web-backend
alias ui := web-frontend
alias frontend := web-frontend
alias web := web-dev

default:
  @just --list

setup:
  uv sync --dev
  pnpm --dir web install

chat:
  uv run mycode

web-backend:
  uv run mycode web --dev

web-frontend:
  pnpm --dir web dev

web-dev:
  #!/usr/bin/env bash
  set -euo pipefail

  cleanup() {
    kill "${backend_pid:-}" "${frontend_pid:-}" 2>/dev/null || true
    wait
  }
  trap cleanup EXIT
  trap 'exit 0' INT TERM

  uv run mycode web --dev &
  backend_pid=$!
  pnpm --dir web dev &
  frontend_pid=$!

  wait -n

py-check:
  uv run ruff check .
  uv run ruff format --check .
  uv run ty check

web-check:
  pnpm --dir web check
  pnpm --dir web typecheck

check: py-check web-check

py-test:
  uv run pytest -n auto

web-test:
  pnpm --dir web test

test: py-test web-test

ci: check test

fmt:
  uv run ruff check --fix .
  uv run ruff format .
  pnpm --dir web check:fix

build:
  uv build --package mycode-sdk
  uv build --package mycode-cli