python-experiments/flake.nix at main · michaelmnemonic/python-experiments · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
{
  description = "Experiements with python";

  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
  };

  outputs = {
    self,
    nixpkgs,
  }: let
    # Define 'forAllSystems' for properties that shall be build for x86_64 *and* aarch64
    systems = ["x86_64-linux" "aarch64-linux"];
    forAllSystems = nixpkgs.lib.genAttrs systems;
    pkgs = forAllSystems (system: nixpkgs.legacyPackages.${system});
  in {
    packages = forAllSystems (system: {
      pyflame = pkgs.${system}.python3Packages.buildPythonPackage rec {
        pname = "pyflame";
        version = "0.3.2";
        pyproject = true;

        src = pkgs.${system}.fetchPypi {
          inherit pname;
          inherit version;
          hash = "sha256-j15RRngb3e84ezMXCyfPxb6Qf64BeVFttWSnI/MOUSE=";
        };

        nativeBuildInputs = [pkgs.${system}.python3Packages.setuptools];

        dontCheckRuntimeDeps = true;
        doCheck = false;
      };
    });

    devShells = forAllSystems (system: {
      default = pkgs.${system}.mkShell {
        buildInputs = with pkgs.${system}; [
          # basics
          gitMinimal

          #python
          python313
          pyright
          ruff
          python313Packages.ipykernel
          python313Packages.matplotlib

          # nix
          nil
          alejandra
        ];
      };
    });
  };
}