From edc5b5522f95bfb9bb761e967f8afdebc10e2eea Mon Sep 17 00:00:00 2001
From: Ashwin Prabhakar <ashwin.prabhakar@qti.qualcomm.com>
Date: Sat, 13 Jun 2026 06:41:31 +0200
Subject: [PATCH 1/2] assimp: Add new recipe for Open Asset Import Library
 (Assimp)

Add a new recipe for the Open Asset Import Library (Assimp) using
the latest upstream git source. This library provides a unified
interface to import various 3D model formats.

Signed-off-by: Ashwin Prabhakar <ashwin.prabhakar@qti.qualcomm.com>
---
 meta-oe/recipes-graphics/assimp/assimp_git.bb | 39 +++++++++++++++++++
 1 file changed, 39 insertions(+)
 create mode 100644 meta-oe/recipes-graphics/assimp/assimp_git.bb

diff --git a/meta-oe/recipes-graphics/assimp/assimp_git.bb b/meta-oe/recipes-graphics/assimp/assimp_git.bb
new file mode 100644
index 00000000000..13d1002946e
--- /dev/null
+++ b/meta-oe/recipes-graphics/assimp/assimp_git.bb
@@ -0,0 +1,39 @@
+SUMMARY = "Open Asset Import Library"
+DESCRIPTION = "The Open Asset Import Library (assimp) is a portable Open Source \
+library to import various well-known 3D model formats in a uniform manner."
+HOMEPAGE = "https://github.com/assimp/assimp"
+SECTION = "devel"
+
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=f2d38c9e0d63058b051065fb7b1102a8"
+
+DEPENDS = "zlib"
+
+SRC_URI = "git://github.com/assimp/assimp.git;protocol=https;branch=master"
+
+SRCREV = "1962da5ac484434524e7a25d566046edd932f901"
+
+PV = "5.x+git${SRCPV}"
+
+inherit cmake
+
+EXTRA_OECMAKE = "\
+    -DASSIMP_BUILD_ASSIMP_TOOLS=OFF \
+    -DASSIMP_BUILD_TESTS=OFF \
+    -DASSIMP_LIB_INSTALL_DIR=${baselib} \
+    -DCMAKE_INSTALL_PREFIX=${prefix} \
+    -DCMAKE_INSTALL_LIBDIR=${baselib} \
+    -DCMAKE_SKIP_RPATH=ON \
+    -DCMAKE_BUILD_WITH_INSTALL_RPATH=OFF \
+"
+
+do_install:append() {
+
+    sed -i \
+        -e "s:${WORKDIR}.*:${prefix}:g" \
+        -e "s:${TMPDIR}.*:${prefix}:g" \
+        ${D}${libdir}/pkgconfig/assimp.pc
+
+    find ${D} -name "*assimp*cmake*" -delete
+    find ${D} -name "*.la" -delete
+}

From 4a8bca0553db0e510b6f02a1a9f4db7df3616967 Mon Sep 17 00:00:00 2001
From: Ashwin Prabhakar <ashwin.prabhakar@qti.qualcomm.com>
Date: Sat, 13 Jun 2026 06:43:08 +0200
Subject: [PATCH 2/2] vkmark: add recipe for Vulkan graphics benchmark

Add an initial recipe for vkmark to enable Vulkan performance testing.
This tool allows for benchmarking various Vulkan rendering scenes and
can be used to validate graphics drivers on target hardware.

Signed-off-by: Ashwin Prabhakar <ashwin.prabhakar@qti.qualcomm.com>

vkmark: fix build parse errors by making XCB support conditional

The current default PACKAGECONFIG explicitly enforces 'xcb'.
This causes build failures on distributions (like Yoe) that
lack 'x11' in their DISTRO_FEATURES, as 'libxcb' and
'xcb-util-wm' are skipped during parsing.

Fix this by dynamically adding 'xcb' to PACKAGECONFIG only
when 'x11' is present in DISTRO_FEATURES.

Signed-off-by: Ashwin Prabhakar <ashwin.prabhakar@qti.qualcomm.com>
---
 .../recipes-benchmark/vkmark/vkmark_git.bb    | 31 +++++++++++++++++++
 1 file changed, 31 insertions(+)
 create mode 100644 meta-oe/recipes-benchmark/vkmark/vkmark_git.bb

diff --git a/meta-oe/recipes-benchmark/vkmark/vkmark_git.bb b/meta-oe/recipes-benchmark/vkmark/vkmark_git.bb
new file mode 100644
index 00000000000..906ba85216d
--- /dev/null
+++ b/meta-oe/recipes-benchmark/vkmark/vkmark_git.bb
@@ -0,0 +1,31 @@
+SUMMARY = "Vulkan benchmark"
+DESCRIPTION = "vkmark is an extensible Vulkan benchmarking suite with targeted, configurable scenes."
+HOMEPAGE = "https://github.com/vkmark/vkmark"
+
+LICENSE = "LGPL-2.1-or-later"
+LIC_FILES_CHKSUM = "file://COPYING-LGPL2.1;md5=4fbd65380cdd255951079008b364516c"
+
+SRC_URI = "git://github.com/vkmark/vkmark.git;protocol=https;branch=master"
+SRCREV = "83a128d65b1adddfacb4fa2e555a7e90817a7266"
+
+PV = "2025.01+git${SRCPV}"
+
+inherit meson pkgconfig
+
+DEPENDS = " \
+    assimp \
+    glm \
+    vulkan-loader \
+"
+
+PACKAGECONFIG ??= "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'xcb', '', d)} wayland kms"
+
+PACKAGECONFIG[xcb] = "-Dxcb=true,-Dxcb=false,libxcb xcb-util-wm"
+PACKAGECONFIG[wayland] = "-Dwayland=true,-Dwayland=false,wayland wayland-native wayland-protocols"
+PACKAGECONFIG[kms] = "-Dkms=true,-Dkms=false,libdrm virtual/libgbm"
+
+FILES:${PN} += " \
+    ${libdir}/vkmark/*.so \
+    ${datadir}/vkmark \
+    ${mandir}/man1/vkmark.1* \
+"