[FR E-Reporting] Implement and send invoice lifecycle messages

src/Apps/FR/EDocument_FR/EReportingFR/app/src/Core/EDocHelpers.Codeunit.al

@@ -4,13 +4,69 @@
 // ------------------------------------------------------------------------------------------------
 namespace Microsoft.eServices.EDocument.Formats;
 
+using Microsoft.eServices.EDocument;
 using Microsoft.Foundation.Company;
 using Microsoft.Sales.Customer;
+using Microsoft.Utilities;
 
 codeunit 10991 "EDoc. Helpers"
 {
     Access = Internal;
 
+    [EventSubscriber(ObjectType::Codeunit, Codeunit::"Data Classification Eval. Data", 'OnCreateEvaluationDataOnAfterClassifyTablesToNormal', '', false, false)]
+    local procedure ClassifyDataSensitivity()
+    var
+        DataClassificationEvalData: Codeunit "Data Classification Eval. Data";
+    begin
+        DataClassificationEvalData.SetTableFieldsToNormal(Database::"FR E-Invoice Lifecycle");
+        DataClassificationEvalData.SetTableFieldsToNormal(Database::"FR E-Invoice Lifecycle VAT");
+    end;
+
+    [EventSubscriber(ObjectType::Table, Database::"E-Document", 'OnBeforeModifyEvent', '', false, false)]
+    local procedure SetClearanceDateOnModify(var Rec: Record "E-Document"; var xRec: Record "E-Document"; RunTrigger: Boolean)
+    var
+        EDocumentServiceStatus: Record "E-Document Service Status";
+        EDocumentService: Record "E-Document Service";
+    begin
+        if not GetFrenchEDocumentService(Rec, EDocumentService, EDocumentServiceStatus) then
+            exit;
+
+        case EDocumentServiceStatus.Status of
+            EDocumentServiceStatus.Status::Approved,
+            EDocumentServiceStatus.Status::Cleared:
+                if Rec."Clearance Date" = 0DT then
+                    Rec."Clearance Date" := CurrentDateTime();
+            EDocumentServiceStatus.Status::Rejected,
+            EDocumentServiceStatus.Status::"Not Cleared":
+                Rec."Clearance Date" := 0DT;
+        end;
+    end;
+
+    local procedure IsFrenchElectronicDocumentFormat(EDocumentFormat: Enum "E-Document Format"): Boolean
+    begin
+        exit(
+            EDocumentFormat in
+            [EDocumentFormat::"E-Reporting FR", EDocumentFormat::"Peppol BIS 3.0 FR", EDocumentFormat::"Factur-X FR"]);
+    end;
+
+    procedure GetFrenchEDocumentService(EDocument: Record "E-Document"; var EDocumentService: Record "E-Document Service"; var EDocumentServiceStatus: Record "E-Document Service Status"): Boolean
+    begin
+        EDocumentService.SetLoadFields("Document Format");
+        if (EDocument.Service <> '') and EDocumentService.Get(EDocument.Service) then
+            if IsFrenchElectronicDocumentFormat(EDocumentService."Document Format") then
+                exit(EDocumentServiceStatus.Get(EDocument."Entry No", EDocumentService.Code));
+
+        EDocumentServiceStatus.SetRange("E-Document Entry No", EDocument."Entry No");
+        if EDocumentServiceStatus.FindSet() then
+            repeat
+                if EDocumentService.Get(EDocumentServiceStatus."E-Document Service Code") then
+                    if IsFrenchElectronicDocumentFormat(EDocumentService."Document Format") then
+                        exit(true);
+            until EDocumentServiceStatus.Next() = 0;
+
+        exit(false);
+    end;
+
     procedure FindFieldByName(RecRef: RecordRef; FieldName: Text; var FieldRefResult: FieldRef): Boolean
     var
         i: Integer;

src/Apps/FR/EDocument_FR/EReportingFR/app/src/Core/FREInvoiceLifecycle.Table.al

@@ -0,0 +1,246 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace Microsoft.eServices.EDocument.Formats;
+
+using Microsoft.eServices.EDocument;
+using Microsoft.Finance.Currency;
+using Microsoft.Sales.Receivables;
+
+table 10970 "FR E-Invoice Lifecycle"
+{
+    Caption = 'FR E-Invoice Lifecycle';
+    DataClassification = CustomerContent;
+    DrillDownPageId = "FR E-Invoice Lifecycles";
+    InherentPermissions = X;
+    LookupPageId = "FR E-Invoice Lifecycles";
+    ReplicateData = false;
+
+    fields
+    {
+        field(1; "Entry No."; Integer)
+        {
+            AutoIncrement = true;
+            Caption = 'Entry No.';
+            DataClassification = SystemMetadata;
+            ToolTip = 'Specifies the entry number of the lifecycle occurrence.';
+        }
+        field(2; "E-Document Entry No."; Integer)
+        {
+            Caption = 'E-Document Entry No.';
+            DataClassification = SystemMetadata;
+            TableRelation = "E-Document"."Entry No";
+            ToolTip = 'Specifies the related e-document entry.';
+        }
+        field(3; "Lifecycle Status"; Enum "FR E-Invoice Lifecycle Status")
+        {
+            Caption = 'Lifecycle Status';
+            DataClassification = SystemMetadata;
+            ToolTip = 'Specifies the French electronic invoice lifecycle status.';
+        }
+        field(4; "Source Occurrence ID"; Guid)
+        {
+            Caption = 'Source Occurrence ID';
+            DataClassification = SystemMetadata;
+            ToolTip = 'Specifies the unique identifier of the source event that triggered this occurrence.';
+        }
+        field(5; "Original Occurrence Entry No."; Integer)
+        {
+            Caption = 'Original Occurrence Entry No.';
+            DataClassification = SystemMetadata;
+            TableRelation = "FR E-Invoice Lifecycle"."Entry No.";
+            ToolTip = 'Specifies the entry number of the original Collected occurrence that this reversal references.';
+        }
+        field(6; "Reported Amount"; Decimal)
+        {
+            AutoFormatExpression = Rec."Currency Code";
+            AutoFormatType = 1;
+            Caption = 'Reported Amount';
+            DataClassification = CustomerContent;
+            ToolTip = 'Specifies the amount reported for this lifecycle occurrence.';
+        }
+        field(7; "Currency Code"; Code[10])
+        {
+            Caption = 'Currency Code';
+            DataClassification = CustomerContent;
+            TableRelation = Currency;
+            ToolTip = 'Specifies the currency of the reported amount. Blank represents the local currency.';
+        }
+        field(8; "Event Date"; Date)
+        {
+            Caption = 'Event Date';
+            DataClassification = CustomerContent;
+            ToolTip = 'Specifies the date of the lifecycle event.';
+        }
+        field(9; "Invoice Cust. Ledger Entry No."; Integer)
+        {
+            Caption = 'Invoice Customer Ledger Entry No.';
+            DataClassification = SystemMetadata;
+            TableRelation = "Cust. Ledger Entry"."Entry No.";
+            ToolTip = 'Specifies the customer ledger entry of the invoice related to this lifecycle occurrence.';
+        }
+        field(10; "Payment Cust. Ledger Entry No."; Integer)
+        {
+            Caption = 'Payment Customer Ledger Entry No.';
+            DataClassification = SystemMetadata;
+            TableRelation = "Cust. Ledger Entry"."Entry No.";
+            ToolTip = 'Specifies the customer ledger entry of the payment related to this lifecycle occurrence.';
+        }
+        field(11; "Detailed Ledger Entry No."; Integer)
+        {
+            Caption = 'Detailed Customer Ledger Entry No.';
+            DataClassification = SystemMetadata;
+            TableRelation = "Detailed Cust. Ledg. Entry"."Entry No.";
+            ToolTip = 'Specifies the detailed customer ledger entry that triggered this lifecycle occurrence.';
+        }
+        field(12; "E-Document Message Entry No."; Integer)
+        {
+            Caption = 'E-Document Message Entry No.';
+            DataClassification = SystemMetadata;
+            ToolTip = 'Specifies the related E-Document message entry.';
+        }
+        field(13; "Processing Status"; Enum "FR E-Invoice Lifecycle Proc.")
+        {
+            Caption = 'Processing Status';
+            DataClassification = SystemMetadata;
+            ToolTip = 'Specifies the processing status of the lifecycle occurrence.';
+        }
+        field(14; "Created At"; DateTime)
+        {
+            Caption = 'Created At';
+            DataClassification = SystemMetadata;
+            ToolTip = 'Specifies when the lifecycle occurrence was created.';
+        }
+        field(15; "Last Error"; Text[2048])
+        {
+            Caption = 'Last Error';
+            DataClassification = CustomerContent;
+            ToolTip = 'Specifies the last processing error for the lifecycle occurrence.';
+        }
+        field(16; "Invoice Issue Date"; Date)
+        {
+            Caption = 'Invoice Issue Date';
+            DataClassification = CustomerContent;
+            ToolTip = 'Specifies the issue date of the invoice frozen at the time of capture.';
+        }
+        field(17; "Invoice Receipt At"; DateTime)
+        {
+            Caption = 'Invoice Receipt At';
+            DataClassification = CustomerContent;
+            ToolTip = 'Specifies the date and time the invoice was received by the platform, frozen at capture.';
+        }
+        field(18; "Sender Platform ID"; Text[50])
+        {
+            Caption = 'Sender Platform ID';
+            DataClassification = CustomerContent;
+            ToolTip = 'Specifies the identifier of the approved platform that sent the invoice.';
+        }
+        field(19; "Sender Platform Scheme"; Code[4])
+        {
+            Caption = 'Sender Platform Scheme';
+            DataClassification = SystemMetadata;
+            ToolTip = 'Specifies the identifier scheme of the sender platform.';
+        }
+        field(20; "Sender Platform Name"; Text[100])
+        {
+            Caption = 'Sender Platform Name';
+            DataClassification = CustomerContent;
+            ToolTip = 'Specifies the name of the approved platform that sent the invoice.';
+        }
+        field(21; "Invoice Issuer ID"; Text[50])
+        {
+            Caption = 'Invoice Issuer ID';
+            DataClassification = CustomerContent;
+            ToolTip = 'Specifies the identifier (SIREN) of the invoice issuer.';
+        }
+        field(22; "Invoice Issuer Scheme"; Code[4])
+        {
+            Caption = 'Invoice Issuer Scheme';
+            DataClassification = SystemMetadata;
+            ToolTip = 'Specifies the identifier scheme of the invoice issuer.';
+        }
+        field(23; "Invoice Issuer Name"; Text[100])
+        {
+            Caption = 'Invoice Issuer Name';
+            DataClassification = CustomerContent;
+            ToolTip = 'Specifies the name of the invoice issuer.';
+        }
+        field(24; "E-Document Service Code"; Code[20])
+        {
+            Caption = 'E-Document Service Code';
+            DataClassification = SystemMetadata;
+            TableRelation = "E-Document Service";
+            ToolTip = 'Specifies the service selected for the lifecycle occurrence and its message.';
+        }
+    }
+
+    keys
+    {
+        key(PK; "Entry No.")
+        {
+            Clustered = true;
+        }
+        key(Occurrence; "E-Document Entry No.", "Source Occurrence ID", "Lifecycle Status")
+        {
+            Unique = true;
+        }
+        key(EDocument; "E-Document Entry No.", "Created At")
+        {
+        }
+        key(QueuedMessage; "E-Document Entry No.", "E-Document Message Entry No.", "Processing Status", "Created At")
+        {
+        }
+        key(DetailedLedgerEntry; "Lifecycle Status", "Detailed Ledger Entry No.")
+        {
+        }
+    }
+
+    trigger OnModify()
+    begin
+        TestImmutableFields();
+    end;
+
+    trigger OnDelete()
+    begin
+        Error(DeleteOccurrenceErr);
+    end;
+
+    trigger OnRename()
+    begin
+        Error(ImmutableOccurrenceErr);
+    end;
+
+    local procedure TestImmutableFields()
+    var
+        PersistedFREInvoiceLifecycle: Record "FR E-Invoice Lifecycle";
+    begin
+        PersistedFREInvoiceLifecycle.Get(Rec."Entry No.");
+        if (Rec."E-Document Entry No." <> PersistedFREInvoiceLifecycle."E-Document Entry No.") or
+           (Rec."Lifecycle Status" <> PersistedFREInvoiceLifecycle."Lifecycle Status") or
+           (Rec."Source Occurrence ID" <> PersistedFREInvoiceLifecycle."Source Occurrence ID") or
+           (Rec."Original Occurrence Entry No." <> PersistedFREInvoiceLifecycle."Original Occurrence Entry No.") or
+           (Rec."Reported Amount" <> PersistedFREInvoiceLifecycle."Reported Amount") or
+           (Rec."Currency Code" <> PersistedFREInvoiceLifecycle."Currency Code") or
+           (Rec."Event Date" <> PersistedFREInvoiceLifecycle."Event Date") or
+           (Rec."Invoice Cust. Ledger Entry No." <> PersistedFREInvoiceLifecycle."Invoice Cust. Ledger Entry No.") or
+           (Rec."Payment Cust. Ledger Entry No." <> PersistedFREInvoiceLifecycle."Payment Cust. Ledger Entry No.") or
+           (Rec."Detailed Ledger Entry No." <> PersistedFREInvoiceLifecycle."Detailed Ledger Entry No.") or
+           (Rec."Created At" <> PersistedFREInvoiceLifecycle."Created At") or
+           (Rec."Invoice Issue Date" <> PersistedFREInvoiceLifecycle."Invoice Issue Date") or
+           (Rec."Invoice Receipt At" <> PersistedFREInvoiceLifecycle."Invoice Receipt At") or
+           (Rec."Sender Platform ID" <> PersistedFREInvoiceLifecycle."Sender Platform ID") or
+           (Rec."Sender Platform Scheme" <> PersistedFREInvoiceLifecycle."Sender Platform Scheme") or
+           (Rec."Sender Platform Name" <> PersistedFREInvoiceLifecycle."Sender Platform Name") or
+           (Rec."Invoice Issuer ID" <> PersistedFREInvoiceLifecycle."Invoice Issuer ID") or
+           (Rec."Invoice Issuer Scheme" <> PersistedFREInvoiceLifecycle."Invoice Issuer Scheme") or
+              (Rec."Invoice Issuer Name" <> PersistedFREInvoiceLifecycle."Invoice Issuer Name") or
+              (Rec."E-Document Service Code" <> PersistedFREInvoiceLifecycle."E-Document Service Code")
+        then
+            Error(ImmutableOccurrenceErr);
+    end;
+
+    var
+        DeleteOccurrenceErr: Label 'A French electronic invoice lifecycle occurrence cannot be deleted.';
+        ImmutableOccurrenceErr: Label 'The regulatory identity and values of a French electronic invoice lifecycle occurrence cannot be changed.';
+}

src/Apps/FR/EDocument_FR/EReportingFR/app/src/Core/FREInvoiceLifecycleError.Codeunit.al

@@ -0,0 +1,35 @@
+// ------------------------------------------------------------------------------------------------
+// Copyright (c) Microsoft Corporation. All rights reserved.
+// Licensed under the MIT License. See License.txt in the project root for license information.
+// ------------------------------------------------------------------------------------------------
+namespace Microsoft.eServices.EDocument.Formats;
+
+codeunit 10989 "FR E-Invoice Lifecycle Error"
+{
+    Access = Internal;
+    InherentEntitlements = X;
+    Permissions = tabledata "FR E-Invoice Lifecycle" = m;
+    TableNo = "FR E-Invoice Lifecycle";
+
+    trigger OnRun()
+    begin
+        if Rec."Processing Status" = Rec."Processing Status"::"Message Sent" then
+            exit;
+        Session.LogMessage(
+            '0000TDQ', LifecycleWorkerFailedTelemetryMsg, Verbosity::Error,
+            DataClassification::SystemMetadata, TelemetryScope::All,
+            'Category', LifecycleTelemetryCategoryTok);
+        Session.LogMessage(
+            '0000TDT', LifecycleWorkerDiagnosticTelemetryMsg, Verbosity::Error,
+            DataClassification::SystemMetadata, TelemetryScope::ExtensionPublisher,
+            'Category', LifecycleTelemetryCategoryTok, 'ErrorCallStack', GetLastErrorCallStack());
+        Rec."Processing Status" := Rec."Processing Status"::Failed;
+        Rec."Last Error" := CopyStr(GetLastErrorText(true), 1, MaxStrLen(Rec."Last Error"));
+        Rec.Modify();
+    end;
+
+    var
+        LifecycleWorkerFailedTelemetryMsg: Label 'French e-invoice lifecycle message processing failed.', Locked = true;
+        LifecycleWorkerDiagnosticTelemetryMsg: Label 'French e-invoice lifecycle message processing failed with an internal error.', Locked = true;
+        LifecycleTelemetryCategoryTok: Label 'French E-Invoice Lifecycle', Locked = true;
+}