[FR E-Reporting] Implement invoice payment lifecycle tracking

src/Apps/FR/EDocument_FR/EReportingFR/app/src/Core/CIIXMLBuilder.Codeunit.al

@@ -304,6 +304,10 @@ codeunit 10978 "CII XML Builder"
                 exit('0009');
             ElecAddressScheme::"0002":
                 exit('0002');
+            ElecAddressScheme::"0225":
+                exit('0225');
+            ElecAddressScheme::"9957":
+                exit('9957');
             else
                 exit(Format(ElecAddressScheme));
         end;

src/Apps/FR/EDocument_FR/EReportingFR/app/src/Core/EDocHelpers.Codeunit.al

@@ -4,12 +4,71 @@
 // ------------------------------------------------------------------------------------------------
 namespace Microsoft.eServices.EDocument.Formats;
 
+using Microsoft.eServices.EDocument;
+using Microsoft.eServices.EDocument.Service.Participant;
 using Microsoft.Foundation.Company;
 using Microsoft.Sales.Customer;
+using Microsoft.Utilities;
 
 codeunit 10991 "EDoc. Helpers"
 {
     Access = Internal;
+    Permissions = tabledata "E-Document" = m,
+                  tabledata "E-Document Service Status" = m;
+
+    [EventSubscriber(ObjectType::Codeunit, Codeunit::"Data Classification Eval. Data", 'OnCreateEvaluationDataOnAfterClassifyTablesToNormal', '', false, false)]
+    local procedure ClassifyDataSensitivity()
+    var
+        DataClassificationEvalData: Codeunit "Data Classification Eval. Data";
+    begin
+        DataClassificationEvalData.SetTableFieldsToNormal(Database::"FR E-Invoice Lifecycle");
+        DataClassificationEvalData.SetTableFieldsToNormal(Database::"FR E-Invoice Lifecycle VAT");
+    end;
+
+    [EventSubscriber(ObjectType::Table, Database::"E-Document", 'OnBeforeModifyEvent', '', false, false)]
+    local procedure SetClearanceDateOnModify(var Rec: Record "E-Document"; var xRec: Record "E-Document"; RunTrigger: Boolean)
+    var
+        EDocumentServiceStatus: Record "E-Document Service Status";
+        EDocumentService: Record "E-Document Service";
+    begin
+        if not GetFrenchEDocumentService(Rec, EDocumentService, EDocumentServiceStatus) then
+            exit;
+
+        case EDocumentServiceStatus.Status of
+            EDocumentServiceStatus.Status::Approved,
+            EDocumentServiceStatus.Status::Cleared:
+                if Rec."Clearance Date" = 0DT then
+                    Rec."Clearance Date" := CurrentDateTime();
+            EDocumentServiceStatus.Status::Rejected,
+            EDocumentServiceStatus.Status::"Not Cleared":
+                Rec."Clearance Date" := 0DT;
+        end;
+    end;
+
+    local procedure IsFrenchElectronicDocumentFormat(EDocumentFormat: Enum "E-Document Format"): Boolean
+    begin
+        exit(
+            EDocumentFormat in
+            [EDocumentFormat::"E-Reporting FR", EDocumentFormat::"Peppol BIS 3.0 FR", EDocumentFormat::"Factur-X FR"]);
+    end;
+
+    procedure GetFrenchEDocumentService(EDocument: Record "E-Document"; var EDocumentService: Record "E-Document Service"; var EDocumentServiceStatus: Record "E-Document Service Status"): Boolean
+    begin
+        EDocumentService.SetLoadFields("Document Format");
+        if (EDocument.Service <> '') and EDocumentService.Get(EDocument.Service) then
+            if IsFrenchElectronicDocumentFormat(EDocumentService."Document Format") then
+                exit(EDocumentServiceStatus.Get(EDocument."Entry No", EDocumentService.Code));
+
+        EDocumentServiceStatus.SetRange("E-Document Entry No", EDocument."Entry No");
+        if EDocumentServiceStatus.FindSet() then
+            repeat
+                if EDocumentService.Get(EDocumentServiceStatus."E-Document Service Code") then
+                    if IsFrenchElectronicDocumentFormat(EDocumentService."Document Format") then
+                        exit(true);
+            until EDocumentServiceStatus.Next() = 0;
+
+        exit(false);
+    end;
 
     procedure FindFieldByName(RecRef: RecordRef; FieldName: Text; var FieldRefResult: FieldRef): Boolean
     var
@@ -46,7 +105,9 @@ codeunit 10991 "EDoc. Helpers"
     begin
         CompanyInformation.Get();
         if CompanyInformation."Registration No." = '' then
-            Error(SIRENRequiredErr);
+            RaiseCompanyInformationError(
+                CompanyInformation,
+                StrSubstNo(SIRENRequiredErr, CompanyInformation.FieldCaption("Registration No."), CompanyInformation.TableCaption()));
     end;
 
     procedure CheckSIRETNotEmpty()
@@ -55,7 +116,33 @@ codeunit 10991 "EDoc. Helpers"
     begin
         CompanyInformation.Get();
         if CompanyInformation."SIRET No." = '' then
-            Error(SIRETRequiredErr);
+            RaiseCompanyInformationError(
+                CompanyInformation,
+                StrSubstNo(SIRETRequiredErr, CompanyInformation.FieldCaption("SIRET No."), CompanyInformation.TableCaption()));
+    end;
+
+    procedure CheckSellerElectronicAddress(EDocumentServiceCode: Code[20])
+    var
+        CompanyInformation: Record "Company Information";
+        ServiceParticipant: Record "Service Participant";
+    begin
+        if HasServiceParticipantAddress(EDocumentServiceCode, Enum::"E-Document Source Type"::Company, '') then
+            exit;
+
+        CompanyInformation.Get();
+        if CompanyInformation."SIRET No." <> '' then
+            exit;
+        if CompanyInformation."Registration No." <> '' then
+            exit;
+        if CompanyInformation.GetVATRegistrationNumber() <> '' then
+            exit;
+
+        RaiseCompanyInformationError(
+            CompanyInformation,
+            StrSubstNo(
+                SellerElectronicAddressRequiredErr, CompanyInformation.FieldCaption("SIRET No."),
+                CompanyInformation.FieldCaption("Registration No."), CompanyInformation.FieldCaption("VAT Registration No."),
+                ServiceParticipant.TableCaption()));
     end;
 
     procedure CheckSellerCountryCode()
@@ -64,12 +151,20 @@ codeunit 10991 "EDoc. Helpers"
     begin
         CompanyInformation.Get();
         if CompanyInformation."Country/Region Code" = '' then
-            Error(SellerCountryCodeRequiredErr);
+            RaiseCompanyInformationError(
+                CompanyInformation,
+                StrSubstNo(SellerCountryCodeRequiredErr, CompanyInformation.FieldCaption("Country/Region Code"), CompanyInformation.TableCaption()));
     end;
 
     procedure CheckBuyerElectronicAddress(var SourceDocumentHeader: RecordRef)
+    begin
+        CheckBuyerElectronicAddress(SourceDocumentHeader, '');
+    end;
+
+    procedure CheckBuyerElectronicAddress(var SourceDocumentHeader: RecordRef; EDocumentServiceCode: Code[20])
     var
         Customer: Record Customer;
+        ServiceParticipant: Record "Service Participant";
         FRCIIXMLBuilder: Codeunit "CII XML Builder";
         CustomerNoFieldRef: FieldRef;
         CustomerNo: Code[20];
@@ -81,16 +176,97 @@ codeunit 10991 "EDoc. Helpers"
         if CustomerNo = '' then
             exit;
 
+        if HasServiceParticipantAddress(EDocumentServiceCode, Enum::"E-Document Source Type"::Customer, CustomerNo) then
+            exit;
+
+        Customer.SetLoadFields("FR Electronic Address", "FR Elec. Address Scheme", "VAT Registration No.");
         if not Customer.Get(CustomerNo) then
             exit;
 
-        if Customer."FR Electronic Address" = '' then
-            Error(BuyerElectronicAddressRequiredErr, Customer."No.");
+        if Customer."FR Electronic Address" <> '' then begin
+            if Customer."FR Elec. Address Scheme" = Customer."FR Elec. Address Scheme"::" " then
+                RaiseCustomerError(
+                    Customer, StrSubstNo(BuyerElectronicAddressSchemeRequiredErr, Customer.FieldCaption("FR Elec. Address Scheme")));
+            exit;
+        end;
+        if Customer."VAT Registration No." <> '' then
+            exit;
+
+        RaiseCustomerError(
+            Customer,
+            StrSubstNo(
+                BuyerElectronicAddressRequiredErr, Customer.FieldCaption("FR Electronic Address"),
+                Customer.FieldCaption("VAT Registration No."), ServiceParticipant.TableCaption()));
+    end;
+
+    procedure HasServiceParticipantAddress(EDocumentServiceCode: Code[20]; ParticipantType: Enum "E-Document Source Type"; ParticipantNo: Code[20]): Boolean
+    var
+        ServiceParticipant: Record "Service Participant";
+    begin
+        exit(HasServiceParticipantAddress(EDocumentServiceCode, ParticipantType, ParticipantNo, ServiceParticipant));
+    end;
+
+    procedure HasServiceParticipantAddress(EDocumentServiceCode: Code[20]; ParticipantType: Enum "E-Document Source Type"; ParticipantNo: Code[20]; var ServiceParticipant: Record "Service Participant"): Boolean
+    var
+        ParticipantAddressErrorInfo: ErrorInfo;
+        HasIdentifier: Boolean;
+        HasScheme: Boolean;
+    begin
+        if EDocumentServiceCode = '' then
+            exit(false);
+        if not ServiceParticipant.Get(EDocumentServiceCode, ParticipantType, ParticipantNo) then
+            exit(false);
+
+        HasIdentifier := ServiceParticipant."Participant Identifier" <> '';
+        HasScheme := ServiceParticipant."FR Identifier Scheme" <> ServiceParticipant."FR Identifier Scheme"::" ";
+        if HasIdentifier <> HasScheme then begin
+            ParticipantAddressErrorInfo.Title(StrSubstNo(SetupIncompleteTitleLbl, ServiceParticipant.TableCaption()));
+            ParticipantAddressErrorInfo.Message(
+                StrSubstNo(ServiceParticipantAddressIncompleteErr, ServiceParticipant.FieldCaption("Participant Identifier"), ServiceParticipant.FieldCaption("FR Identifier Scheme")));
+            ParticipantAddressErrorInfo.DetailedMessage(ParticipantAddressErrorInfo.Message());
+            ParticipantAddressErrorInfo.RecordId(ServiceParticipant.RecordId());
+            ParticipantAddressErrorInfo.PageNo(Page::"Service Participants");
+            ParticipantAddressErrorInfo.AddNavigationAction(StrSubstNo(ShowRecordLbl, ServiceParticipant.TableCaption()));
+            Error(ParticipantAddressErrorInfo);
+        end;
+
+        exit(HasIdentifier);
+    end;
+
+    local procedure RaiseCompanyInformationError(CompanyInformation: Record "Company Information"; ErrorMessage: Text)
+    var
+        CompanyInformationErrorInfo: ErrorInfo;
+    begin
+        CompanyInformationErrorInfo.Title(StrSubstNo(SetupIncompleteTitleLbl, CompanyInformation.TableCaption()));
+        CompanyInformationErrorInfo.Message(ErrorMessage);
+        CompanyInformationErrorInfo.DetailedMessage(ErrorMessage);
+        CompanyInformationErrorInfo.RecordId(CompanyInformation.RecordId());
+        CompanyInformationErrorInfo.PageNo(Page::"Company Information");
+        CompanyInformationErrorInfo.AddNavigationAction(StrSubstNo(ShowRecordLbl, CompanyInformation.TableCaption()));
+        Error(CompanyInformationErrorInfo);
+    end;
+
+    local procedure RaiseCustomerError(Customer: Record Customer; ErrorMessage: Text)
+    var
+        CustomerErrorInfo: ErrorInfo;
+    begin
+        CustomerErrorInfo.Title(StrSubstNo(SetupIncompleteTitleLbl, Customer.TableCaption()));
+        CustomerErrorInfo.Message(ErrorMessage);
+        CustomerErrorInfo.DetailedMessage(ErrorMessage);
+        CustomerErrorInfo.RecordId(Customer.RecordId());
+        CustomerErrorInfo.PageNo(Page::"Customer Card");
+        CustomerErrorInfo.AddNavigationAction(StrSubstNo(ShowRecordLbl, Customer.TableCaption()));
+        Error(CustomerErrorInfo);
     end;
 
     var
-        SIRENRequiredErr: Label 'Registration No. must be specified in Company Information for French e-invoicing.';
-        SIRETRequiredErr: Label 'SIRET No. must be specified in Company Information for French e-invoicing.';
-        BuyerElectronicAddressRequiredErr: Label 'Electronic Address must be specified for Customer %1 for French e-invoicing.', Comment = '%1 = Customer No.';
-        SellerCountryCodeRequiredErr: Label 'Country/Region Code must be specified in Company Information for French e-invoicing.';
+        SetupIncompleteTitleLbl: Label '%1 setup is incomplete', Comment = '%1 = table caption';
+        ShowRecordLbl: Label 'Show %1', Comment = '%1 = table caption';
+        SIRENRequiredErr: Label '%1 must be specified in %2 for French e-invoicing.', Comment = '%1 = Registration No. field caption, %2 = Company Information table caption';
+        SIRETRequiredErr: Label '%1 must be specified in %2 for French e-invoicing.', Comment = '%1 = SIRET No. field caption, %2 = Company Information table caption';
+        SellerElectronicAddressRequiredErr: Label '%1, %2, %3, or a %4 identifier must be specified for the company for French e-invoicing.', Comment = '%1 = SIRET No. field caption, %2 = Registration No. field caption, %3 = VAT Registration No. field caption, %4 = Service Participant table caption';
+        BuyerElectronicAddressRequiredErr: Label '%1, %2, or a %3 identifier must be specified for the customer for French e-invoicing.', Comment = '%1 = Electronic Address field caption, %2 = VAT Registration No. field caption, %3 = Service Participant table caption';
+        BuyerElectronicAddressSchemeRequiredErr: Label '%1 must be specified for the customer for French e-invoicing.', Comment = '%1 = Electronic Address Scheme field caption';
+        SellerCountryCodeRequiredErr: Label '%1 must be specified in %2 for French e-invoicing.', Comment = '%1 = Country/Region Code field caption, %2 = Company Information table caption';
+        ServiceParticipantAddressIncompleteErr: Label '%1 and %2 must both be specified for French electronic invoicing.', Comment = '%1 = Participant Identifier field caption, %2 = French Identifier Scheme field caption';
 }

src/Apps/FR/EDocument_FR/EReportingFR/app/src/Core/ElectronicAddressScheme.Enum.al

@@ -20,4 +20,16 @@ enum 10976 "Electronic Address Scheme"
     {
         Caption = 'SIREN (0002)';
     }
+    value(3; " ")
+    {
+        Caption = ' ';
+    }
+    value(4; "0225")
+    {
+        Caption = 'FRCTC electronic address (0225)';
+    }
+    value(5; "9957")
+    {
+        Caption = 'French VAT number (9957)';
+    }
 }